/*
 * Copyright 2022 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     https://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

plugins {
    id "nowinandroid.android.test"
    id 'nowinandroid.spotless'
}

android {
    namespace 'com.google.samples.apps.nowinandroid.benchmark'

    defaultConfig {
        minSdk 23
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
    }

    buildTypes {
        // This benchmark buildType is used for benchmarking, and should function like your
        // release build (for example, with minification on). It's signed with a debug key
        // for easy local/CI testing.
        benchmark {
            debuggable true
            signingConfig debug.signingConfig
            matchingFallbacks = ['release']
        }
    }

    targetProjectPath = ":app"
    experimentalProperties["android.experimental.self-instrumenting"] = true
}

dependencies {
    implementation libs.androidx.test.core
    implementation libs.androidx.test.espresso.core
    implementation libs.androidx.test.ext
    implementation libs.androidx.test.runner
    implementation libs.androidx.test.rules
    implementation libs.androidx.test.uiautomator
    implementation libs.androidx.benchmark.macro
    implementation libs.androidx.profileinstaller
}

androidComponents {
    beforeVariants(selector().all()) {
        enabled = buildType == "benchmark"
    }
}